package {

    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import org.libspark.betweenas3.BetweenAS3;
    import org.libspark.betweenas3.tweens.ITween;
    import org.libspark.betweenas3.easing.Quad;
    import org.libspark.betweenas3.events.TweenEvent;
    import jp.nya.project.character.FrogA;
    import jp.nya.project.controls.Btn;

    [SWF(backgroundColor="#FFFFFF", width="600", height="240", frameRate="30")]

    public class Main extends Sprite {
        // プロパティ
        private var itween:ITween;
        private var playing:Boolean = false;
        private var frog:FrogA;
        private var playBtn:Btn;
        private var stopBtn:Btn;

        // コンストラクタ
        public function Main() {
            init();
        }

        // メソッド
        private function init():void {
            frog = new FrogA();
            addChild(frog);
            frog.x = 300;
            frog.y = 180;
            frog.addEventListener(FrogA.JUMP, jumpComplete, false, 0, true);
            itween = BetweenAS3.tween(frog, {x: 500}, {x: 100}, 1, Quad.easeOut);
            itween.addEventListener(TweenEvent.COMPLETE, complete, false, 0, true);
            playBtn = new Btn();
            addChild(playBtn);
            playBtn.x = 260;
            playBtn.y = 220;
            playBtn.init({label: "play"});
            playBtn.addEventListener(MouseEvent.CLICK, play, false, 0, true);
            stopBtn = new Btn();
            addChild(stopBtn);
            stopBtn.x = 340;
            stopBtn.y = 220;
            stopBtn.init({label: "stop"});
            stopBtn.enabled = false;
        }
        private function play(evt:MouseEvent):void {
            if (!playing) {
                frog.x = 100;
                frog.swingHead();
            }
            itween.play();
            playBtn.clicked = true;
            playBtn.removeEventListener(MouseEvent.CLICK, play);
            stopBtn.enabled = true;
            stopBtn.addEventListener(MouseEvent.CLICK, stop, false, 0, true);
        }
        private function stop(evt:MouseEvent):void {
            itween.stop();
            reset();
        }
        private function complete():void {
            frog.jump();
        }
        private function reset():void {
            playBtn.clicked = false;
            playBtn.addEventListener(MouseEvent.CLICK, play, false, 0, true);
            stopBtn.enabled = false;
            stopBtn.removeEventListener(MouseEvent.CLICK, stop);
        }
        private function jumpComplete(evt:Event):void {
            reset();
        }

    }

}